הפן הטכני קל איתי

[Gordi]

תודה לשניכם

[Og]

אני אתעמק בזה בקרוב (אני מקווה), אין לי זמן עכשיו.

[Og]

החלטתי לא לדבר על החסרונות של השיטה הזו או על כמה אוברקיל קובץ האצווה הזה אלא להתייחס אליו כאילו הוא הפתרון הסופי ולכן רק לציין בעיות *מהותיות* איתו.

נתחיל באיך הקובץ הבתול מגיב אצלי: הוא לא מוצא את דוסבוקס ומבקש שאתקין אותו בתקיית ברירת המחדל, שזה לא יעזור כי הוא כבר מותקן אצלי בתיקיית ברירת המחדל.

אז ניסיתי לקחת את התבנית של Og צעד אחד קדימה

זה מצחיק שאתה אומר את זה, כי אם היית לוקח את הבדיקה היחידה שה"תבנית" שלי עושה, לא הייתה לך הבעיה שהזכרתי לעיל.
במילים אחרות, הקובץ לא בודק את התיקייה של מערכות X64 ולכן, לא יעבוד במערכות כאלה (ולדעתי הן הרבה יותר נפוצות ממערכות של 32 ביט).

הנה שינוי קטן שיתקן את זה:

הצג/הסתר תוכן

קוד: בחירת הכל

@ECHO OFF

:: ######################################################################
:: #  Old-Games.Org DOSBox Game Launcher                                #
:: #  ----------------------------------                                #
:: #                                                                    #
:: #  Usage: After installing DOSBox in the default location,           #
:: #         place this file in the same directory as the Go.Bat file   #
:: #         and run this file. This file will then try to run Go.bat   #
:: #         using DOSBox.                                              #
:: #                                                                    #
:: #         If a *.conf file named "MasaDBL.conf" exists in the        #
:: #         same directory, it will be used as the DOSBox conf file.   #
:: #                                                                    #
:: #         If an argument is supplied to this script, it will be      #
:: #         used instead of the default "Go.bat" file.                 #
:: #                                                                    #
:: #  DOSBox is an open-source DOS emulator.                            #
:: #  More details can be found at: http://www.dosbox.com/              #
:: #                                                                    #
:: #  For questions and comments, please visit our forum:               #
:: #     http://www.old-games.org/f                                     #
:: #                                                                    #
:: ######################################################################

:: THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, 
:: EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES 
:: OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND 
:: NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS 
:: BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN 
:: ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN 
:: CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE 
:: SOFTWARE. 

:: ==========================================================================

:: Set this to 1 in order to view debug printouts
SET DEBUG=0

IF "%DEBUG%"=="1" GOTO :SET_DEBUG
GOTO :SET_RELEASE

:SET_DEBUG
SET PrintDebug=ECHO - 
SET ExecDebug=
GOTO :START

:SET_RELEASE
SET PrintDebug=::
SET ExecDebug=::
GOTO :START


:START
SET DOSBoxDownloadPage="http://sourceforge.net/projects/dosbox/files/latest/download"
SET LAUNCH_FILENAME=Go.bat
SET DOSBOX_EXEC=DOSBox.exe
SET DOSBOX_PARAMS=  -exit -noconsole
SET DOSBOX_LATEST=DOSBox-0.74
SET APP_NAME=MasaDBL

SET CONF_FILENAME=%APP_NAME%.conf
SET CACHE_FILENAME=%APP_NAME%_Cache.txt

:: Header

ECHO.
ECHO   ___  _     _        ____                                            
ECHO  / _ \^| ^| __^| ^|      / ___^| __ _ _ __ ___   ___  ___       ___  _ __ __ _ 
ECHO ^| ^| ^| ^| ^|/ _` ^|_____^| ^|  _ / _` ^| '_ ` _ \ / _ \/ __^|     / _ \^| '__/ _` ^|
ECHO ^| ^|_^| ^| ^| (_^| ^|_____^| ^|_^| ^| (_^| ^| ^| ^| ^| ^| ^|  __/\__ \    ^| (_) ^| ^| ^| (_^| ^|
ECHO  \___/^|_^|\__,_^|      \____^|\__,_^|_^| ^|_^| ^|_^|\___^|^|___/ (_) \___/^|_^|  \__, ^|
ECHO                                                                     ^|___/ 
ECHO.
ECHO.

ECHO             --===== Old-Games.Org DOSBox Launcher v0.1 =====--
ECHO.
ECHO.

:: This is the file we will try to launch with DOSBox
SET LAUNCH_PATH="%CD%\%LAUNCH_FILENAME%"

:: If an argument is supplied, use it as the file to launch (instead of the default "Go.bat")
IF NOT "%1"=="" (
	IF EXIST "%1" (
		%PrintDebug% Overwriting default launch path with: %1
		SET LAUNCH_PATH="%1"
	)
)

%PrintDebug% Launch path is: %LAUNCH_PATH%


:: Try to locate DOSBox


:: First, try to read the path to DOSBox from the cache:
%PrintDebug% Trying to read DOSBox path from cache
IF EXIST "%USERPROFILE%\Local Settings\Application Data" ( 
	SET CACHE_PATH="%USERPROFILE%\Local Settings\Application Data\%APP_NAME%\%CACHE_FILENAME%"
	mkdir "%USERPROFILE%\Local Settings\Application Data\%APP_NAME%\" > NUL 2>&1
)
IF EXIST "%LOCALAPPDATA%" ( 
	SET CACHE_PATH="%LOCALAPPDATA%\%APP_NAME%\%CACHE_FILENAME%"
	mkdir "%LOCALAPPDATA%\%APP_NAME%\" > NUL 2>&1
)

IF NOT EXIST %CACHE_PATH% GOTO :DOSBOX_TRY_DEFAULT_PATH


%PrintDebug% Cache path is: %CACHE_PATH%

:: We found a cached file, try to read from cache:
SET /p DOSBOX_CACHED_PATH=<%CACHE_PATH%
%PrintDebug% DOSBOX_CACHED_PATH path is: %DOSBOX_CACHED_PATH%
IF NOT EXIST %DOSBOX_CACHED_PATH% GOTO :DOSBOX_TRY_DEFAULT_PATH

%PrintDebug% Cached path exists!

SET DOSBoxPath=%DOSBOX_CACHED_PATH%
GOTO :FOUND_DOSBOX

:DOSBOX_TRY_DEFAULT_PATH
:: Can't find DOSBox using cache, make an educated guess using the default location of the latest installation on x86 OS
SET DOSBoxPath="%programfiles%\%DOSBOX_LATEST%\%DOSBOX_EXEC%"
%PrintDebug% Trying to use predefined DOSBox path: %DOSBoxPath%

IF EXIST %DOSBoxPath% (
	%PrintDebug% Using predefined DOSBox path
	GOTO :FOUND_DOSBOX
)

:: Can't find DOSBox using cache, make an educated guess using the default location of the latest installation on x64 OS
SET DOSBoxPath="%programfiles(x86)%\%DOSBOX_LATEST%\%DOSBOX_EXEC%"
%PrintDebug% Trying to use predefined DOSBox path: %DOSBoxPath%

IF EXIST %DOSBoxPath% (
	%PrintDebug% Using predefined DOSBox path
	GOTO :FOUND_DOSBOX
)

%PrintDebug% Can't find DOSBox in predefined path
GOTO :DOSBOX_SEARCH

:DOSBOX_SEARCH
:: If we can't find DOSBox in the default location, try locating it in the ProgramFiles directory
%PrintDebug% Searching for a DOSBox executable in %programfiles%:

ECHO Searching for DOSBox (x86 OS)...
:: If multiple entries are found, the final path should be the last (thus, latest) one
FOR /f "delims=" %%a IN ('dir /B /S "%programfiles%\""*%DOSBOX_EXEC%*"') DO (
	%PrintDebug% Found a DOSBox executable at: %%a
	SET DOSBoxPath="%%a"
)

IF EXIST %DOSBoxPath% GOTO :FOUND_DOSBOX

ECHO Searching for DOSBox (x64 OS)...
:: If multiple entries are found, the final path should be the last (thus, latest) one
FOR /f "delims=" %%a IN ('dir /B /S "%programfiles(x86)%\""*%DOSBOX_EXEC%*"') DO (
	%PrintDebug% Found a DOSBox executable at: %%a
	SET DOSBoxPath="%%a"
)

IF EXIST %DOSBoxPath% GOTO :FOUND_DOSBOX

GOTO :CANT_FIND_DOSBOX

:CANT_FIND_DOSBOX
ECHO.
ECHO ERROR: Can't find DOSBox!
ECHO You need to install DOSBox in order to use this program.
GOTO :TO_INSTALL_DOSBOX

:TO_INSTALL_DOSBOX
ECHO.
SET /P InstallDosbox=Would you like to open the DOSBox download page [Y or N]? 
IF "%InstallDosbox%" == "Y" GOTO :LAUNCH_BROWSER
IF "%InstallDosbox%" == "y" GOTO :LAUNCH_BROWSER

IF "%InstallDosbox%" == "N" GOTO :DONT_LAUNCH_BROWSER
IF "%InstallDosbox%" == "n" GOTO :DONT_LAUNCH_BROWSER
GOTO :TO_INSTALL_DOSBOX

:LAUNCH_BROWSER
ECHO Launching Browser
%PrintDebug% DOSBox download page is: %DOSBoxDownloadPage%
START "" %DOSBoxDownloadPage% 
ECHO Please Install DOSBox (using default options) and retry...
GOTO :END_BAD

:DONT_LAUNCH_BROWSER
ECHO Please Install DOSBox (using default options) and retry...
GOTO :END_BAD

:FOUND_DOSBOX
%PrintDebug% Final DOSBox path set to: %DOSBoxPath%

::Cache DOSBox path for the future
IF NOT [%CACHE_PATH%] == [] (
	
	ECHO %DOSBoxPath% > %CACHE_PATH% 2>NUL
)

:: Now try to locate Go.Bat:
IF EXIST %LAUNCH_PATH% GOTO :FOUND_GO
GOTO :CANT_FIND_GO

:FOUND_GO
%PrintDebug% Found %LAUNCH_PATH%, launching game!

SET CONF_PARAM=
IF EXIST %CONF_FILENAME% (
	%PrintDebug% Using *.conf file: %CONF_FILENAME%
	SET CONF_PARAM= -conf "%CD%\%CONF_FILENAME%" 
)
SET DOSBOX_COMMAND=%DOSBoxPath% %LAUNCH_PATH% %DOSBOX_PARAMS% %CONF_PARAM%
CALL :FILE_DIR_FROM_PATH DOSBOX_DIR %DOSBoxPath%
%PrintDebug% DOSBox directory is: %DOSBOX_DIR%
IF "%DOSBOX_DIR%"=="" GOTO :INTERNAL_ERROR
SET DOSBOX_DIR="%DOSBOX_DIR%"
IF NOT EXIST %DOSBOX_DIR% GOTO :INTERNAL_ERROR
%PrintDebug% Starting the following command: %DOSBOX_COMMAND%
::ECHO Launching game!
CALL :PRINT_SUCCESS
TIMEOUT 2 > NUL
START "" /D%DOSBOX_DIR% /B %DOSBOX_COMMAND%
GOTO :END_GOOD

:CANT_FIND_GO
ECHO.
ECHO ERROR: Can't find "%LAUNCH_FILENAME%" in the current directory!
ECHO Are you sure you have extracted this program to the correct directory?
ECHO.
ECHO Please move this program to the correct directory 
ECHO   (the one containing %LAUNCH_FILENAME%) and try again...
GOTO :END_BAD

:: Given a full path to a file, extract the folder which contains the file and save it as %<resultVar>%
:FILE_DIR_FROM_PATH <resultVar> <pathVar>
(
    SET "%~1=%~dp2"
    EXIT /b
)

:PRINT_SUCCESS (
SET ECHO_WIDTH=ECHO                    
%ECHO_WIDTH%       /\          /\          /\
%ECHO_WIDTH%    /\//\\/\    /\//\\/\    /\//\\/\
%ECHO_WIDTH% /\//\\\///\\/\//\\\///\\/\//\\\///\\/\
%ECHO_WIDTH%//\\\//\/\\///\\\//\/\\///\\\//\/\\///\\
%ECHO_WIDTH%\\//\/                            \/\\//
%ECHO_WIDTH% \/            Launching             \/
%ECHO_WIDTH% /\              Game!               /\
%ECHO_WIDTH%//\\/\                            /\//\\
%ECHO_WIDTH%\\///\\/\//\\\///\\/\//\\\///\\/\//\\\//
%ECHO_WIDTH% \/\\///\\\//\/\\///\\\//\/\\///\\\//\/
%ECHO_WIDTH%    \/\\//\/    \/\\//\/    \/\\//\/
%ECHO_WIDTH%       \/          \/          \/
EXIT /B
)

:INTERNAL_ERROR
ECHO ERROR: Internal Error
GOTO :END_BAD

:END_BAD
::COLOR C
ECHO.
ECHO For questions and comments, please visit our forum at:
ECHO     http://www.old-games.org/f
ECHO.
PAUSE
EXIT /B 1

:END_GOOD
%ExecDebug% PAUSE
EXIT

ואני מבין שאין ברירה אלא להשתמש בפלט באנגלית, אבל לפחות יכולת לקשר לאתר עם הסבר בעברית במקום להורדה של דוסבוקס...

אני גם לא כ"כ מבין את הלוגיקה של התכנות במקומות מסויימים, אפילו נראה כאילו מכונה כתבה את הקוד ולא אדם... השתמשת באיזשהו ממיר? או שלקחת שלד של קוד מוכן מאיפשהו?

[Gordi]

החלטתי לא לדבר על החסרונות של השיטה הזו או על כמה אוברקיל קובץ האצווה הזה אלא להתייחס אליו כאילו הוא הפתרון הסופי ולכן רק לציין בעיות *מהותיות* איתו.

אוקיי, כמובן שאני מכבד את ההחלטה הזו. אבל בעוד שאת החלק של האוברקיל אני יכול לנחש בעצמי, דע שאני עדיין מאוד אשמח לקבל רשימה (גם אם קצרה ומתומצתת) של חסרונות לא מהותיים או בעיות שאתה צופה שיהיו עם קובץ האצווה הזה.

זה מצחיק שאתה אומר את זה, כי אם היית לוקח את הבדיקה היחידה שה"תבנית" שלי עושה, לא הייתה לך הבעיה שהזכרתי לעיל.
במילים אחרות, הקובץ לא בודק את התיקייה של מערכות X64 ולכן, לא יעבוד במערכות כאלה (ולדעתי הן הרבה יותר נפוצות ממערכות של 32 ביט).

אופס, אתה בהחלט צודק. אני חייב לומר להגנתי שבדקתי את העניין (באמצעות חיפוש בגוגל) ומשום מה הגעתי למסקנה שבמקרה הספציפי של דוסבוקס, מספיק לחפש ב-%programFiles%. את הבדיקה שלך הנוספת שלך הסברתי לעצמי באמצעות המשפט שכתבת מיד אחר כך:

זה רק משהו שרשמתי עכשיו. לא בדקתי את זה וסביר להניח שיש טעויות תחביר ו/או טעויות לוגיות - זה לא משנה, זה נועד רק להמחיש את הנקודה.

בדיעבד אני אכן רואה שטעיתי.
טעות, טועים, בכל זאת, אני רק בנאדם ולא מכונה (אבל תכף נגיע לזה...).
בכל מקרה, תודה על התיקון

ואני מבין שאין ברירה אלא להשתמש בפלט באנגלית, אבל לפחות יכולת לקשר לאתר עם הסבר בעברית במקום להורדה של דוסבוקס...

אתה צודק, ובסופו של דבר זה אכן מה שתכננתי לעשות, אבל לצורך ההדגמה התעצלתי לבנות דף כזה, והסתפקתי בעמוד ההורדה.

אני גם לא כ"כ מבין את הלוגיקה של התכנות במקומות מסויימים, אפילו נראה כאילו מכונה כתבה את הקוד ולא אדם... השתמשת באיזשהו ממיר? או שלקחת שלד של קוד מוכן מאיפשהו?

למרבה הפאדיחה, דווקא לא. כתבתי את זה בעצמי (להוציא קסמים כאלו ואחרים של מציאת קובץ בתיקייה, קריאה מתוך קובץ לתוך משתנה, Ascii Art וכד').
מאוד מסקרן אותי לדעת למה אתה מתייחס, תוכל בבקשה לתת דוגמא כלשהי?

[Octarine]

אפילו נראה כאילו מכונה כתבה את הקוד ולא אדם...

למרבה הפאדיחה, דווקא לא. כתבתי את זה בעצמי

גורדי - האדם הראשון שכשל במבחן טורינג.

[Og]

אוקיי, כמובן שאני מכבד את ההחלטה הזו. אבל בעוד שאת החלק של האוברקיל אני יכול לנחש בעצמי, דע שאני עדיין מאוד אשמח לקבל רשימה (גם אם קצרה ומתומצתת) של חסרונות לא מהותיים או בעיות שאתה צופה שיהיו עם קובץ האצווה הזה.

כל העקרון מאחורי ההחלטה הוא לחסוך ממני לכתוב את החסרונות הלא מהותיים.
חוץ מזה, ככה אם תהיה בעיה אני תמיד יכול להגיד שצפיתי אותה מראש

למרבה הפאדיחה, דווקא לא. כתבתי את זה בעצמי (להוציא קסמים כאלו ואחרים של מציאת קובץ בתיקייה, קריאה מתוך קובץ לתוך משתנה, Ascii Art וכד').
מאוד מסקרן אותי לדעת למה אתה מתייחס, תוכל בבקשה לתת דוגמא כלשהי?

אני לא חושב שאני יכול להסביר את התחושה שהתקבלה אצלי שקראתי את הקוד לראשונה (לפחות לא בקצרה). לעומת זאת, היו פקודה או שתיים שהבנתי לא נכון בהתחלה וגם ה"קסמים" שעליהם אתה מדבר תרמו לתחושה הזו. בנוסף פשוט לא חשבתי שתשקיע כל כך הרבה בדבר כזה (וזה באמת הזמן להביע את הערכתי לכמות העבודה שהשקעת).
כשאני קורא את הקוד עכשיו, זה כבר לא כ"כ מרגיש כמו קודם.



אוקיי, אז בוא נניח שהשלב הזה גמור. שאלה בקשר לשלב הבא: אתה מתכוון להציע כמה "פרופילים" בצורת קובצי conf ? ואם כן, איך אתה מתכנן לעשות את זה (מבחינה טכנית)?

[Gordi]

גורדי - האדם הראשון שכשל במבחן טורינג.

LOL. מזכיר לי קצת את זה (והנה עוד אחד על הדרך).

כל העקרון מאחורי ההחלטה הוא לחסוך ממני לכתוב את החסרונות הלא מהותיים.

As you wish:-)

אוקיי, אז בוא נניח שהשלב הזה גמור. שאלה בקשר לשלב הבא: אתה מתכוון להציע כמה "פרופילים" בצורת קובצי conf ? ואם כן, איך אתה מתכנן לעשות את זה (מבחינה טכנית)?

חשבתי שאולי בשלב ראשון נציע את הקובץ הבודד לכולם בצורה אחידה כחלק מדף הורדת המשחק (כפי שהוצע כאן בעבר). בצורה הזאת נוכל אולי לקבל איזשהו פידבק לפני שאנחנו נדרשים להשקיע את מה שצריך בהכנת ותחזוק החבילות.
נשמע הגיוני?

[Og]

חשבתי שאולי בשלב ראשון נציע את הקובץ הבודד לכולם בצורה אחידה כחלק מדף הורדת המשחק (כפי שהוצע כאן בעבר). בצורה הזאת נוכל אולי לקבל איזשהו פידבק לפני שאנחנו נדרשים להשקיע את מה שצריך בהכנת ותחזוק החבילות.
נשמע הגיוני?

יאללא, לך על זה.

[Gordi]

סיימתי לדחוס את המשחקים הרלוונטיים, הנה התוצאות:
-ריימן, מ-418M ל-104M, חסכון של 314 מגה.
-ריימן יוצר, מ-311M ל-67M, חסכון של 244 מגה.
-ריימן חשבון, מ-218M ל-83M, חסכון של 135 מגה.
-ריימן אנגלית, מ-218M ל-83M, חסכון של 135 מגה.
-המסע שלי בעולם הדמיון, מ-385M ל-148M, חסכון של 237 מגה.
[...]
אני אעלה את הקבצים החדשים בעתיד הקרוב.

מבלי חלילה להאיץ, רציתי לשאול אם נתקלת בבעיה והאם אפשר לעזור

[Og]

לא נתקלתי בבעיה וגם לא שכחתי. אני שוב מתנצל על המחסור ביכולת לעזור בזמן האחרון והקרוב, ברגע שאוכל אני אעשה את זה.

[Radioactive Grandpa]

יאללה, עוד נושא.
זה:
http://www.old-games.org/hebrew.php" target="_blank
מדריך די בעייתי. לדעתי צריך להיות ברור עוד יותר שמדובר בשלוש אלטרנטיבות שונות (סעיפים 1,2,4. מה עושה שם 3 בכלל?..). כלומר, לכל אחד כותרת עצמאית. ויש בכלל צורך באפשרויות 2 ו-4 (שהרי עקרונית הן צריכות לספק הסברים גם כן)? אני לא זוכר שאי פעם ההצעות האלו עלו כאן.
הסיבה שהתחלתי בזה היא בכל אופן סעיף 1. מכיוון שכל משחק שמורד מהאתר אמור להיות מופעל ע"י go.bat (ועל כך מתבסס הפרוייקט האחרון שדשנו בו), אפשר להוסיף את הפקודה לקובץ האצווה, ולמעשה לוותר על כמעט כל ההוראות. בנוסף כמובן אפשר להעיר שהחבילה מיועדת למשחקים שהורדו מהאתר, ובמקרה אחר יש לערוך את קובץ האצווה לפי שם הקובץ וכו'.
ועוד עניין הוא שלדעתי, מכיוון שאין מדובר רק בתוכן תיאורטי אלא גם במקור עצמו להורדת החבילה, הקישור צריך להיות בולט בהרבה מסתם מילה יחידה במשפט שמדבר על זה (הוא הדין גם לגבי המדריכים האלה).
(כשנגיע לחבילות מיוחדות, גם יהיה אפשר לכלול את זה, בהנחה שצירוף החבילה מלכתחילה למשחקים שדורשים אותה והכללתה בקובץ ה-go הוא פתרון לא רצוי.)

[Ingsoc]

לא יותר פשוט לכלול את הקובץ בהורדה של המשחקים הזקוקים לו כדי להציג עברית ולסדר כך שהוא יופעל כחלק מ-Go?

[Radioactive Grandpa]

(כשנגיע לחבילות מיוחדות, גם יהיה אפשר לכלול את זה, בהנחה שצירוף החבילה מלכתחילה למשחקים שדורשים אותה והכללתה בקובץ ה-go הוא פתרון לא רצוי.)

וההנחה הזו, היא עקב כך שגורדי לא רצה לכלול את DOSBox בהורדות כשהרעיון עלה, וגם לא רק את קובץ האצווה המיוחד שנדון לאחרונה ושנועד לתפעל את DOSBox.

[Ingsoc]

(כשנגיע לחבילות מיוחדות, גם יהיה אפשר לכלול את זה, בהנחה שצירוף החבילה מלכתחילה למשחקים שדורשים אותה והכללתה בקובץ ה-go הוא פתרון לא רצוי.)

וההנחה הזו, היא עקב כך שגורדי לא רצה לכלול את DOSBox בהורדות כשהרעיון עלה, וגם לא רק את קובץ האצווה המיוחד שנדון לאחרונה ושנועד לתפעל את DOSBox.

אני חושב שיש הבדל בין צירוף הדוסבוקס, שהיא תוכנה שיחסית שוקלת הרבה ועדיין מתעדכנת (כך שנצרך כל הזמן לעדכן את הגרסה או לאפשר הורדה של גרסה מיושנת), לבין הקובץ הקטן של העברית.

[Og]

מה עושה שם 3 בכלל?

ביישומים מאד ספציפיים במערכות הפעלה ישנות (וגם בXP אם תיקון העברית מסעיף 2 מותקן) זה יכול לעבוד.

ויש בכלל צורך באפשרויות 2 ו-4 (שהרי עקרונית הן צריכות לספק הסברים גם כן)? אני לא זוכר שאי פעם ההצעות האלו עלו כאן.

לא הבנתי את מה שכתוב בסוגריים, אבל כן, יש צורך והן עלו הרבה כאן בתקופה שXP עוד הייתה חדשה ודוסבוקס היה עם פחות תאימות.

בהנחה שצירוף החבילה מלכתחילה למשחקים שדורשים אותה והכללתה בקובץ ה-go הוא פתרון לא רצוי

למיטב זכרוני, כל משחק רלוונטי שנוסף לאתר לאחר ההוראות בעמוד הנ"ל (וגם משחקים שנעשה בהם שינוי והועלו מחדש) אכן כלל את הפונט העברי ואת הפעלתו ב-GO.BAT.
הכללת התיקון על כל המשחקים הרלוונטיים באתר היא (לעניות דעתי שאינה משמשת תחליף לדעתו של גורדי) פתרון רצוי.
דא עקא, טרם נמצא מתנדב שיבצע פתרון זה (שוב, בהנחה שדעתו של גורדי כשלי).